## How do I remove a key from a dictionary?

Pass the key you want to remove as the left argument to the _ (drop) operator, and pass the dictionary as its right argument:

q)dict: `a`b`c ! 1 2 3
q)dict
a| 1
b| 2
c| 3
q)`b _ dict
a| 1
c| 3
q)

If you reverse the order of the arguments, the removal still works:

q)dict _ `b
a| 1
c| 3
q)

Although we can’t think of a good reason to do this, you might come across it. As our commenter Attila pointed out, however, you are more likely to see this overload in its assignment form:

q)dict _: `b / same as dict: dict _ `b
q)dict
a| 1
c| 3
q)

Meanwhile, you can remove multiple keys at once by passing a list of keys as the left argument to _ (drop):

q)`a`c _ dict
b| 2
q)

Reversing the arguments does not work in this case:

q)dict _ `a`c
‘type
q)

## What are 0!, 1! and 2!?

When !’s left argument is a positive integer, it sets the key fields of a table:

q)flip `a`b`c ! (1 2 3; 1 2 3; 1 2 3)
a b c
—–
1 1 1
2 2 2
3 3 3
q)1! flip `a`b`c ! (1 2 3; 1 2 3; 1 2 3)
a| b c
-| —
1| 1 1
2| 2 2
3| 3 3
q)2! flip`a`b`c ! (1 2 3; 1 2 3; 1 2 3)
a b| c
—| –
1 1| 1
2 2| 2
3 3| 3

When !’s left argument is zero, it returns an unkeyed table from a keyed table:

q)0! ([a: 1 2 3; b: 1 2 3]; c: 1 2 3)
a b c
—–
1 1 1
2 2 2
3 3 3
q)

An arguably more readable equivalent is the xkey function:

q)`a xkey flip `a`b`c ! (1 2 3; 1 2 3; 1 2 3)
a| b c
-| —
1| 1 1
2| 2 2
3| 3 3
q)`a`b xkey flip `a`b`c ! (1 2 3; 1 2 3; 1 2 3)
a b| c
—| –
1 1| 1
2 2| 2
3 3| 3
q)() xkey ([a: 1 2 3; b: 1 2 3]; c: 1 2 3)
a b c
—–
1 1 1
2 2 2
3 3 3
q)

It’s easy to confuse function xkey with key, keys, xcol and xcols.